1-Wire デバイスを使ってみよう

#include <OneWire.h>
OneWire  ds(10);  // on pin 10
#define ONE_WIRE_MAX_SEARCH_NUM 10
#define ONE_WIRE_ID_LENGTH      8

int i,p,r;
struct OneWireDevice {
  uint8_t id[ONE_WIRE_ID_LENGTH];
  uint8_t data;
};
uint8_t foundDeviceNum=0;
uint8_t writeDataBuffer[8] =  {0x00};

OneWireDevice OneWireDev[ONE_WIRE_MAX_SEARCH_NUM];

uint8_t SearchDevice()
{
  foundDeviceNum=0;
  uint8_t rdata[8]={0x00};
  String id="";
  
  if(foundDeviceNum>=ONE_WIRE_MAX_SEARCH_NUM)
    return false;

  while(1){
    /*デバイスの検索*/
    if ( !ds.search(rdata)) {
      if(foundDeviceNum==0){
        Serial.println("Can not find the device");
        ds.reset_search();
        delay(5000);
      } else {
        Serial.print(foundDeviceNum);
        Serial.println("devices were found.");
      }
      break;
      
    } else {
      id= String(rdata[0], 16) + ":"
        + String(rdata[1], 16) + ":"
        + String(rdata[2], 16) + ":"
        + String(rdata[3], 16) + ":"
        + String(rdata[4], 16) + ":"
        + String(rdata[5], 16) + ":"
        + String(rdata[6], 16) + ":"
        + String(rdata[7], 16) ;
   
      Serial.print("Found Device:");
      Serial.print(id);
      Serial.print(" :Managed as index number:");
      Serial.println(foundDeviceNum);
      OneWireDev[foundDeviceNum].id[0]=rdata[0];
      OneWireDev[foundDeviceNum].id[1]=rdata[1];
      OneWireDev[foundDeviceNum].id[2]=rdata[2];
      OneWireDev[foundDeviceNum].id[3]=rdata[3];
      OneWireDev[foundDeviceNum].id[4]=rdata[4];
      OneWireDev[foundDeviceNum].id[5]=rdata[5];
      OneWireDev[foundDeviceNum].id[6]=rdata[6];
      OneWireDev[foundDeviceNum].id[7]=rdata[7];
      foundDeviceNum++;  
    }
  }
  return foundDeviceNum;
}

void display_menu()
{
  Serial.println("");
  Serial.println("// Menu ");
  Serial.println("// 1: Serch Device");
  Serial.println("// 2: Read data from Device(128bytes)");
  Serial.println("// 3: Write data to Device(128bytes) ");
  Serial.println("// 4: Change the writing data");
  Serial.println("// 5: Debug");
  Serial.println("// Select menu:");
}

void menu(byte value)
{
    switch (value) {
    case '1':
      option_1();
      break;
    case '2':
      option_2();
      break;
    case '3':
      option_3();
      break;
    case '4':
      option_4();
      break;
    case '5':
      option_5();
      break;  
    default:
      Serial.println("unexpected command,  try again");
      break;
  }
}

void option_1()
{
  Serial.println("SercheDevice");
  SearchDevice();  
}

void option_2()
{  
  Serial.println("Read data from Device(128bytes)"); 
  Serial.println("Input the index number of target device:");
  while(1)
  {    
    if (Serial.available() > 0) {
        uint8_t ascii = Serial.read();
        uint8_t index = ascii - '0'; 
        
        if(index > (foundDeviceNum-1))
        {
          Serial.println("The number is out of range. Please try again.");
          return;
        }
        read_eeprom(index, 0x00);
        return;      
    }
    delay(10);
  }
}

void option_3()
{
  Serial.println("Write data to Device(128bytes)"); 
  Serial.println("Input the index number of target device:");
  while(1)
  {    
    if (Serial.available() > 0) {
        uint8_t ascii = Serial.read();
        uint8_t index = ascii - '0'; 
        
        if(index > (foundDeviceNum-1))
        {
          Serial.println("The number is out of range. Please try again.");
          return;
        }
          Serial.println(" ");
          Serial.print("Selected Index =");
          Serial.print(index);
          Serial.print(", ROM ID =");
          for (int i = 0; i < 8; i++) {
            Serial.print(OneWireDev[index].id[i], HEX);
            Serial.print(" ");     
          }
          Serial.println(" ");
        write_allusermemoy(index, writeDataBuffer);
        return;      
    }
    delay(10);
  }  
}

void option_5()
{
  Serial.println("Menu no.5 execution..");
  for(int index=0; index < 4; index++){
    for (int i = 0; i < 8; i++) {
      Serial.print(OneWireDev[index].id[i], HEX);
      Serial.print(" ");     
    }
    Serial.println(" ");
  }
}

void option_4(){
    uint8_t dataBuffer_zero[8] =  {0x00};
    uint8_t dataBuffer_incri[8] = {0x00,0x01,0x02,0x03,0x04,0x05,0x06,0x07};
    uint8_t dataBuffer_AA[8] =  {0xAA,0xAA,0xAA,0xAA,0xAA,0xAA,0xAA,0xAA};
    uint8_t dataBuffer_FF[8] =  {0xFF,0xFF,0xFF,0xFF,0xFF,0xFF,0xFF,0xFF};

    Serial.println("The data to be written can be changed.The default is all 0x00");
    Serial.println("1. all 0x000");
    Serial.println("2. incremental data 0x00 - 0x07");
    Serial.println("3. all 0xAA");    
    Serial.println("4. all 0xFF");
    Serial.println("Input number : ");
    Serial.println(" ");
    
    while(1)
    {       
      if (Serial.available() > 0) {
          byte value = Serial.read();
          switch (value) {
          case '1':
            memcpy(writeDataBuffer, dataBuffer_zero, sizeof(dataBuffer_zero));
            Serial.println("Changed to all 0x00");
            return;
          case '2':
            memcpy(writeDataBuffer, dataBuffer_incri, sizeof(dataBuffer_incri));
            Serial.println("Changed toa incremental data 0x00 -0x07");         
            return;
          case '3':
            memcpy(writeDataBuffer, dataBuffer_AA, sizeof(dataBuffer_AA));
            Serial.println("Changed to all 0xAA");         
            return;
          case '4':
            memcpy(writeDataBuffer, dataBuffer_FF, sizeof(dataBuffer_FF));
            Serial.println("Changed to all 0xFF");
            return; 
          default:
            Serial.println("unexpected command");
            return;
          }
       }      
    }
      delay(10);
}


void setup(void) {
  delay(1000);
  Serial.begin(9600);
  Serial.println("Start communicating with 1-Wire Device");
  SearchDevice();
  delay(1000);
} 
 
void loop(void) {
  if(foundDeviceNum){
    display_menu();
    // wait for inputting ascii data from serial port
    while(1)
    {    
      if (Serial.available() > 0) {
          byte value = Serial.read();
          menu(value);  
          break;      
      }
      delay(10);
    }
    delay(200);
  }
  delay(200);
}
/*************************************************************************/
void write_allusermemoy(uint8_t index, uint8_t* dataBuffer){
  Serial.println("Write data to the User memory area(128byte) 8bytes at a time");
  for(byte address=0x00; address<=0x78;address=address+0x08){
    write_eeprom(index, address, dataBuffer);
    delay(100);
  }
} 
/************************** READ_EEPROM ***********************************/
void read_eeprom(uint8_t index, uint8_t address){
  
  uint8_t romid[8] = {0x00};
  uint8_t readdata[128]  = {0x00};

 
  // TargetのROM IDを設定
  for (int i = 0; i < 8; i++) {
    romid[i] = OneWireDev[index].id[i];    
  }

  Serial.println(" ");
  Serial.print("Selected ROM ID =");
  for (int i = 0; i < 8; i++) {
    Serial.print(romid[i], HEX);
    Serial.print(" ");     
  }
  Serial.println(" ");
  
  // Read sequence
  ds.reset();
  ds.write(0x55);           // match command send
  ds.write_bytes(romid, 8); // rom id send
  ds.write(0xf0);           // eeprom read command send
  /*
  The memory address must be specified in 2 bytes. The lower byte is sent first, and the upper byte is sent later.
  The upper byte shall be fixed at 0x00.
  */
  ds.write(address);  //adrees
  ds.write(0x00);     //adrees
 
  /*Read data from EEPROM*/
  Serial.println("User memory Area of this EEPROM DATA (128byte) = ");
  for (int i = 0; i < 128; i++) {
    readdata[i] = ds.read();
  }
 
  /*読み取ったEEPROMの表示*/
  for (int i = 0; i < 128; i++) {
    Serial.print(readdata[i], HEX);
    Serial.print(" "); 
    if(i % 32 == 31) {  // 32個の値ごとに改行
      Serial.println("");
    }       
  } 
  Serial.println(" ");
}
 
/************************** WRITE_EEPROM ***********************************/
void write_eeprom(uint8_t index, uint8_t address, uint8_t* dataBuffer){

  uint8_t romid[8] = {0x00};
  uint8_t readScratchedData[8] = {0x00};
  
  // TargetのROM IDを設定
  for (int i = 0; i < 8; i++) {
    romid[i] = OneWireDev[index].id[i];    
  }   
  /*データをスクラッチパットへの書き込むシーケンス*/
  ds.reset();
  ds.write(0x55);           // match command send
  ds.write_bytes(romid, 8); // rom id send
  ds.write(0x0f);           //scratchpad_write
  /*
  The memory address must be specified in 2 bytes. The lower byte is sent first, and the upper byte is sent later.
  The upper byte shall be fixed at 0x00.
  */
  ds.write(address);        //write address TA1　書き込み先アドレス
  ds.write(0x00);           //write address TA2

  delay(10);
  /*8byteのデータの書き込み*/
  for ( i = 0; i <= 7; i++){
    ds.write(dataBuffer[i]);
  }
  Serial.println("");
  delay(10); 
  
  /*スクラッチパットデータの読み込み（書き込むべきデータのチェックのために行う）*/
  ds.reset();
  ds.write(0x55);           // match command send
  ds.write_bytes(romid, 8); // rom id send
  ds.write(0xaa);           //scratchpad_read

  delay(10);
  /*レジスタ部の読み込み*/
  byte T1=ds.read();
  byte T2=ds.read();
  byte E_S=ds.read();
 
  /*（読み取ったレジスタの表示）*/
  Serial.print("TA1=");
  Serial.print(T1,HEX);
  Serial.print("  TA2=");
  Serial.print(T2,HEX);
  Serial.print("  E/S=");
  Serial.print(E_S,HEX);

  delay(10);
  /*(スクラッチパットのデータ読み込み)*/
  Serial.print(",  read scratchpad deta= ");
  for ( i = 0; i <= 7; i++){
    readScratchedData[i] = ds.read();
  }
 
  /*(読み取ったスクラッチパットの表示)*/
  for ( i = 0; i <= 7; i++) { 
    Serial.print(readScratchedData[i], HEX);
    Serial.print(" ");
  }
  delay(500);

  /*スクラッチパットのコピーをEEPROMに書き込み*/
  ds.reset();
  ds.write(0x55);           // match command send
  ds.write_bytes(romid, 8); // rom id send
  ds.write(0x55);           //scratchpad_copy
  /*
  The memory address must be specified in 2 bytes. The lower byte is sent first, and the upper byte is sent later.
  The upper byte shall be fixed at 0x00.
  */  
  ds.write(address);        //write address TA1
  ds.write(0x00);           //write address TA2
  ds.write(E_S);            //write address e/s
  delay(5);//書き終わるまで待つ
}